APG BURBACKUP 自動執(zhí)行指令

@G-
!#########################################################################################!
!## ##!
!## Script to Backup the APG40 ##!
!## ##!
!## Author: EPADNB ##!
!## Version: 1.10##!
!## ##!
!## 1. Run this script on the Passive Node.##!
!## ##!
!## 2. Configure winfiol by selecting Run -> Traffic Setup and unchecking the##!
!## the "missing semicolon" option.##!
!## ##!
!## 3. Configure winfiol by selecting Channel -> Properties. Click on Target. Make##!
!## sure the exchange type is APG40. Click Add. Type :(32) and click OK##!
!## ##!
!#########################################################################################!

@G-
@PRESERVE
!## Check Node is PASSIVE ##
prcstate
@IF {_line1} = "active" THEN GOTO error1

!## Find out what node we are on ##
hostname
@LENGTH {_line1} {len}
@COPY {_line1} {node} {len} 1
@INC {len} -1
@COPY {_line1} {basenodename} 1 {len}

@IF {node} = "a" THEN @SET {nodename}={basenodename}+a
@IF {node} = "b" THEN @SET {nodename}={basenodename}+b
@IF {node} = "a" THEN @SET {othernodename}={basenodename}+b
@IF {node} = "b" THEN @SET {othernodename}={basenodename}+a

@IF {node} = "a" THEN @SET {nodenum}=1
@IF {node} = "b" THEN @SET {nodenum}=2

@IF {node} = "a" THEN @SET {othernode}=b
@IF {node} = "a" THEN @SET {othernodenum}=2
@IF {node} = "b" THEN @SET {othernode}=a
@IF {node} = "b" THEN @SET {othernodenum}=1

!## Collect Information ##
@SET {title} = "Enter Backup Details"
@SET {adminusr} = "Administrator"
@SET {backuptok} = "yes"
@SET {confirm} = "yes"
@LABEL GetInfo
@FORM CREATE {title}
@FORM TEXT "Enter Backup &Name eg. Syd_APG40 :" 2 2 31 3
@FORM EDITTEXT {burname} 33 2 20
@FORM TEXT "Enter Administrator &Username :" 2 7 25 3
@FORM EDITTEXT {adminusr} 27 7 15
@FORM TEXT "Enter Administrator &Password :" 2 12 25 3
@FORM EDITTEXT {adminpsw} 27 12 15
@FORM TEXT "Do you want to backup to &K:\ <yes/no> :" 2 17 34 3
@FORM EDITTEXT {backuptok} 36 17 6
@FORM TEXT "Confirm before APG40 restart <yes/no> :" 2 22 34 3
@FORM EDITTEXT {confirm} 36 22 6
@FORM RUN

@IF {burname} <> "" THEN GOTO QuBackuptoK
@COMMENT "Please enter a Name for the Backup"
@GOTO GetInfo

@LABEL QuBackuptoK
@IF {backuptok} = "y" THEN GOTO BackuptoKyes
@IF {backuptok} = "yes" THEN GOTO BackuptoKyes
@IF {backuptok} = "n" THEN GOTO Confirm
@IF {backuptok} = "no" THEN GOTO Confirm
@COMMENT "Please enter yes or no"
@SET {backuptok} = "yes"
@GOTO GetInfo

@LABEL BackuptoKyes
@SET {backuptok} = "yes"

@LABEL Confirm
@IF {confirm} = "y" THEN GOTO Confirmyes
@IF {confirm} = "yes" THEN GOTO Confirmyes
@IF {confirm} = "n" THEN GOTO QuAdmin
@IF {confirm} = "no" THEN GOTO QuAdmin
@COMMENT "Please enter yes or no"
@SET {confirm} = "yes"
@GOTO GetInfo

@LABEL Confirmyes
@SET {confirm} = "yes"

@LABEL QuAdmin
@IF {adminusr} <> "" THEN GOTO AdminCheck
@COMMENT "Please enter a Name for the Administrator User"
@SET {adminusr} = "Administrator"
@GOTO GetInfo

!## Check Administrator Name and Password ##
@LABEL AdminCheck
net use \\192.168.202.{nodenum}\c$ {adminpsw} /USER:{adminusr}
@SCAN {_line1} "The command completed successfully" {pos}
@IF {pos} <> 0 THEN GOTO DDIcreate
dummy
@COMMENT "Administrator User or Password incorrect. Enter again."
@SET {adminusr} = "Administrator"
@SET {adminpsw} = ""
@GOTO GetInfo

!## Connect to ACTIVE/other node for ddi creation ##
@LABEL DDIcreate
net use \\192.168.202.{nodenum}\c$ /DELETE
@PRESERVE
@IF {node} = "a" THEN GOSUB ConnectB
@IF {node} = "b" THEN GOSUB ConnectA
@IF {Login} <> "ok" THEN END
burbackup -y -savedatadiskinfo c:\bur\{burname}.ddi
@SCAN {_line1} "disks 2-4 successfully saved" {pos}
@IF {pos} = 0 THEN GOTO error2

!## Copy ddi file to PASSIVE node ##
copy c:\bur\{burname}.ddi \\192.168.202.{nodenum}\c$\bur
@SCAN {_line1} "1 file(s) copied" {pos}
@IF {pos} = 0 THEN GOTO error3
exit

!## Backup the first node to D:\ ##
@SET {Locked}=0
@LABEL Bur1
burbackup -y -imagename {burname}_{node}
@SCAN {_line1} "Locked file" {pos}
@IF {pos} <> 0 THEN GOTO LOCKED1
@SCAN {_line1} "burBackup execution completed" {pos}
@IF {pos} = 0 THEN GOSUB error5
@SCAN {_line2} "0 files locked" {pos}
@IF {pos} <> 0 THEN GOTO BurK1
@LABEL Locked1
@INC {Locked} 1
@COMMENT Locked Files were found.
@IF {Locked} > 1 THEN GOTO error6
@COMMENT Attempt Backup Again.
@GOTO Bur1

!## Backup the first node to K:\ if requested ##
@LABEL BurK1
@IF {backuptok} <> "yes" THEN GOTO Reboot
burbackup -y -src d:\ -imgdest \\192.168.202.{othernodenum}\images\node{node}\{burname}_{node}.zip
@IF {_line1} <> "burBackup execution completed" THEN GOSUB error7

!## Connect to ACTIVE node, reboot it to make it PASSIVE ##
@LABEL Reboot
@IF {confirm} <> "yes" THEN GOTO Reboot2
@CONFIRM "The Active node will now reboot. Note: The connection may be lost if the failover is not successful!"
@LABEL Reboot2

!##edited by EWANGHD
start /b shutdown /F /R \\{othernodename}
!prcboot

!## Wait 8 minutes for ACTIVE node to reboot as PASSIVE ##
@COMMENT Waiting 8 minutes for Node "{othernode}" to reboot. ##
@COMMENT If the connection is lost then make Node "{node}" active
@COMMENT and Node "{othernode}" passive before continuing.
@M 8

!## To continue if the connection is lost, place the cursor on ##
!## the next line and press <ctrl b> and then F4 ##

!## Connect to new PASSIVE node
@LABEL ConnectOther
@IF {node} = "a" THEN GOSUB ConnectB
@IF {node} = "b" THEN GOSUB ConnectA
@IF {Login} = "ok" THEN GOTO StartBur2
@CONFIRM Make sure Node "{othernode}" has rebooted. When Node "{othernode}" is passive press continue.
@GOTO ConnectOther

!## Backup second node ##
@LABEL StartBur2
@SET {Locked}=0
@LABEL Bur2
prcstate
@IF {_line1} = "active" THEN GOTO error4
burbackup -y -imagename {burname}_{othernode}
@SCAN {_line1} "Locked file" {pos}
@IF {pos} <> 0 THEN GOTO LOCKED2
@SCAN {_line1} "burBackup execution completed" {pos}
@IF {pos} = 0 THEN GOSUB error5
@SCAN {_line2} "0 files locked" {pos}
@IF {pos} <> 0 THEN GOTO BurK2
@LABEL LOCKED2
@INC {Locked} 1
@COMMENT Locked Files were found.
@IF {Locked} > 1 THEN GOTO error6
@COMMENT Attempt Backup Again.
@GOTO Bur2

!## Backup the second node to K:\ if requested ##
@LABEL BurK2
@IF {backuptok} <> "yes" THEN GOTO End
burbackup -y -src d:\ -imgdest \\192.168.202.{nodenum}\images\node{othernode}\{burname}_{othernode}.zip
@IF {_line1} <> "burBackup execution completed" THEN GOSUB error7

!## Finished ##
@LABEL End
@CLEAR
exit
@COMMENT Backup Finished
@END


!#################### GOSUB Routines ####################
@LABEL error1
@CONFIRM "NODE is not passive. Please log into Passive node."
@END

@LABEL error2
@CONFIRM "Cannot create ddi file."
exit
@END

@LABEL error3
@CONFIRM "Cannot copy ddi file to passive node."
exit
@END

@LABEL error4
@CONFIRM NODE is not passive. Node "{othernode}" should be passive after the reboot
@END

@LABEL error5
@CONFIRM "Burbackup to D:\ failed"
@RETURN

@LABEL error6
@CONFIRM "There were locked files. Need to reboot passive node and try again"
@END

@LABEL error7
@CONFIRM "Backup to K drive failed."
@RETURN

@LABEL ConnectA
@SET {Login}="ok"
set TERM=
telnet 192.168.202.1
@T 2
{adminusr}
{adminpsw}
.
1
prcstate
hostname
@LENGTH {_line1} {len}
@COPY {_line1} {tempnode} {len} 1
@IF {tempnode} = "a" THEN GOTO LoginOK
@CONFIRM Cannot Connect to Node "{othernode}"
@SET {Login}="failed"
@LABEL LoginOK
@RETURN

@LABEL ConnectB
@SET {Login}="ok"
set TERM=
telnet 192.168.202.2
@T 2
{adminusr}
{adminpsw}
.
1
prcstate
hostname
@LENGTH {_line1} {len}
@COPY {_line1} {tempnode} {len} 1
@IF {tempnode} = "b" THEN GOTO LoginOK
@CONFIRM Cannot Connect to Node "{othernode}"
@SET {Login}="failed"
@LABEL LoginOK
@RETURN